8fa87f45f9
A JSON configuration file is generated for core plugins, which maps plugin names with sources to parse for docstrings. The file is then opened by the configuration generator script, which will now favor explicitly listed files to (usually wildcarded) paths passed on its command line. Part-of: <https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/8231>
53 lines
1.0 KiB
Meson
53 lines
1.0 KiB
Meson
if not tracer_hooks
|
|
if get_option('coretracers').enabled()
|
|
error('coretracers plugin enabled but not tracer_hooks')
|
|
endif
|
|
subdir_done()
|
|
endif
|
|
|
|
gst_tracers_sources = [
|
|
'gstlatency.c',
|
|
'gstleaks.c',
|
|
'gststats.c',
|
|
'gsttracers.c',
|
|
'gstfactories.c'
|
|
]
|
|
|
|
gst_tracers_headers = [
|
|
'gstfactories.h',
|
|
'gstlatency.h',
|
|
'gstleaks.h',
|
|
'gstlog.h',
|
|
'gstrusage.h',
|
|
'gststats.h',
|
|
]
|
|
|
|
if gst_debug
|
|
gst_tracers_sources += ['gstlog.c']
|
|
endif
|
|
|
|
if cdata.has('HAVE_GETRUSAGE')
|
|
gst_tracers_sources += ['gstrusage.c']
|
|
endif
|
|
|
|
thread_dep = dependency('threads', required : false)
|
|
|
|
gst_tracers = library('gstcoretracers',
|
|
gst_tracers_sources,
|
|
c_args : gst_c_args,
|
|
include_directories : [configinc],
|
|
dependencies : [gst_dep, thread_dep],
|
|
install : true,
|
|
install_dir : plugins_install_dir,
|
|
)
|
|
plugins += [gst_tracers]
|
|
|
|
doc_sources = []
|
|
foreach s: gst_tracers_sources + gst_tracers_headers
|
|
doc_sources += meson.current_source_dir() / s
|
|
endforeach
|
|
|
|
plugin_sources += {
|
|
'coretracers': pathsep.join(doc_sources)
|
|
}
|